今日の日付のフォルダを作成するバッチ

作業前のバックアップ用など、今日の日付（システム日付）のフォルダを作成することはよくあると思います。今回紹介するのは、Windowsで今日の日付のフォルダを作成するバッチファイルです。

バッチファイルの内容

@ECHO OFF
REM **********************************************
REM 処理内容：システム日付のフォルダを作成するバッチ
REM 作成日：2021/07/13
REM 作成者：marock.tokyo
REM 更新日：
REM 更新者：
REM 更新内容：
REM **********************************************
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
REM メイン処理
:MAIN
    REM ファイルがあるフォルダに移動
    PUSHD %~DP0

    REM システム日付の取得（YYYYMMDD形式）
    SET SYSDATE=%DATE:~-10,4%%DATE:~-5,2%%DATE:~-2,2%

    REM 添え字
    SET EDA=

    :MKDIR
    REM フォルダ作成
    MKDIR %SYSDATE%%EDA%

    REM エラー判断
    IF %ERRORLEVEL%==0 GOTO :FINAL
    
    REM 添え字を付けて再作成
    SET /A EDA_VAL+=1
    SET EDA="_"%EDA_VAL%
    GOTO :MKDIR

GOTO :FINAL

REM 終了処理
:FINAL
    POPD
    ENDLOCAL
    ECHO 終了
EXIT /B

解説

今回のバッチファイルは、バッチファイルを実行したフォルダに今日の日付をyyyymmdd形式にフォーマットしたフォルダを作成します。例えば、2021年7月13日の場合だと、20210713というフォルダを作成します。もし既に20210713フォルダが作成済みの場合、枝番を付けた20210713_1というフォルダを作成します。もし、20210713_1というフォルダがあれば20210713_2というフォルダを作成します。もし、20210713_2という・・・

使い方

バッチファイルがよくわからない方に向けの使い方の説明です。

1. 新規にテキストファイルを作成します（デスクトップなどで右クリック=>新規作成=>テキストドキュメント）。拡張子は「bat」を指定してください。例えば「今日の日付のフォルダ作成.bat」など
2. 作成したファイルを右クリックして編集を選択してください。メモ帳が起動します。
3. 起動したメモ帳に「バッチファイルの内容」で紹介した内容をコピー＆ペーストして保存してください。
4. 作成したファイルをフォルダを作成したいフォルダに移動します。
5. 作成したファイルをダブルクリックして実行すると今日の日付のフォルダが作成されます。